<%
Class DashboardController_Class
    Private m_useLayout
    Private m_title

    Private Sub Class_Initialize()
        m_useLayout = True
        m_title = "Dashboard"
    End Sub

    Public Property Get useLayout
        useLayout = m_useLayout
    End Property

    Public Property Let useLayout(v)
        m_useLayout = v
    End Property

    Public Property Get Title
        Title = m_title
    End Property

    Public Property Let Title(v)
        m_title = v
    End Property

    '-------------------------------------------------------------------------------------------------------------------
    ' GET /dashboard : simple counts
    '-------------------------------------------------------------------------------------------------------------------
    Public Sub index()
        Dim counts, activity, daily, byMethod, byOutcome, industries, imports, maxDaily, i
        Set counts = StatsRepository().ListCounts()
        Set activity = StatsRepository().ActivityCounts()
        Set daily = StatsRepository().DailyActivity(14)
        Set byMethod = StatsRepository().ActivityBy("method")
        Set byOutcome = StatsRepository().ActivityBy("outcome")
        Set industries = StatsRepository().TopIndustries(10)
        Set imports = StatsRepository().RecentImports(5)

        maxDaily = 1
        For i = 0 To daily.Count - 1
            If daily(i)(1) > maxDaily Then maxDaily = daily(i)(1)
        Next
    %>
    <!--#include file="../views/Dashboard/index.asp" -->
    <%
    End Sub

End Class

Dim DashboardController_Class__Singleton
Function DashboardController()
    If IsEmpty(DashboardController_Class__Singleton) Then
        Set DashboardController_Class__Singleton = New DashboardController_Class
    End If
    Set DashboardController = DashboardController_Class__Singleton
End Function
%>